Peinture simple

Le premier programme de peinture électronique s'appelait Sketchpad, créé par Ivan Sutherland, étudiant diplômé du MIT en 1963. À l'aide d'un stylo lumineux, des formes simples pouvaient être dessinées et mises à l'échelle.

Au début des années 80, Andy Warhol dessinait avec enthousiasme des cercles avec MacPaint, et les ordinateurs n'ont toujours pas libéré leur emprise sur l'art à ce jour.

PAINT.BAS est un programme de peinture extrêmement simple qui sert néanmoins de modèle simple pour des approches de programme de peinture plus avancées plus loin dans cette section.

Lors de l'exécution, il vous sera demandé dans quel ÉCRAN vous souhaitez peindre et où, en termes de PSET, vous souhaitez commencer le dessin.

Ensuite, à l'aide du clavier numérique, vous pourrez déplacer le curseur à votre guise, laissant des traces colorées dans son sillage.

Vous pouvez également effacer de manière PRESET ce que vous avez dessiné un pixel à la fois en appuyant sur certaines lettres (voir le code ci-dessous pour les commandes) ou quitter en tapant E.

Votre canevas dépend des invites initiales. Ce qui est constant, cependant, ce sont les options : huit directions de dessin, quinze couleurs à parcourir et des effacements pixel par pixel ou en une seule fois, entièrement gérés par une instruction INKEY$.

PAINT.BAS  est un début, mais c'est un programme très limité. Bien plus pourrait être fait sur un canevas virtuel GW-BASIC.

PAINT.BAS

0 KEY OFF:SCREEN 9:COLOR 4,4:CLS:COLOR 15
1 INPUT"SCREEN(7-9)";D
5 INPUT"COULEUR DE L'ARRIÈRE PLAN (1-15)";A
7 INPUT"COMMENCER AU X POINT";W:INPUT"COMMENCER AU Y POINT";V
15 SCREEN D:COLOR 2,2:CLS:COLOR 15
16 COLOR A,A:CLS:PA=1
20 X=W:Y=V
30 I$=INKEY$:IF I$="" THEN GOTO 30
40 IF I$="8" THEN Y=Y-1
50 IF I$="6" THEN X=X+1
51 IF I$="4" THEN X=X-1
52 IF I$="2" THEN Y=Y+1
53 IF I$="P" THEN PA=PA+1
54 IF I$="C" THEN GOTO 80
55 IF I$="E" THEN GOTO 90
56 IF I$="S" THEN GOTO 0
57 IF I$="A" THEN X=X-1:GOTO 130
58 IF I$="W" THEN Y=Y-1:GOTO 130
59 IF I$="F" THEN X=X+1:GOTO 130
60 IF I$="Z" THEN Y=Y+1:GOTO 130
61 IF I$="7" THEN Y=Y-1:X=X-1
62 IF I$="1" THEN X=X-1:Y=Y+1
63 IF I$="3" THEN Y=Y+1:X=X+1
64 IF I$="9" THEN X=X+1:Y=Y-1
65 IF PA=>16 THEN PA=1
69 PSET(X,Y),PA
70 GOTO 30
80 COLOR A,A:CLS:GOTO 30
90 COLOR 1,1:CLS:COLOR 15
100 SOUND 750,4:SOUND 900,4:PRINT:PRINT:PRINT:PRINT:PRINT"Sortie de PAINT"
110 FOR N=1 TO 4000:NEXT N:END
130 PRESET(X,Y)
140 GOTO 30