Le test de Stroop

GW-Basic, utilisé par PC-Basic

Programme avec Texte Seulement

PC-BASIC

La lecture est tellement automatique chez les adultes que même si le mot ROUGE était affiché dans une couleur différente (disons vert), la lecture du mot ROUGE par une personne interfèrerait avec la reconnaissance de la couleur du mot (vert). Ce phénomène s'appelle "l'effet Stroop", du nom du psychologue John Stroop. Bien qu'il n'ait pas été le premier à remarquer cette théorie de l'interférence, Stroop, en 1935, a été le premier à mener une expérience formelle pour la tester.

Vous n'avez pas besoin qu'une équipe de psychologues arrive à votre porte pour vous faire passer un test Stroop - GW-BASIC peut en mettre un en place.

Exécutez STROOP.BAS, et vous passerez deux tests: lors du premier test, cinq mots sont imprimés à l'écran dont les couleurs correspondent à leurs noms de couleur; dans le deuxième test, un autre ensemble de cinq mots est affiché, cette fois dont les couleurs diffèrent de leurs noms de couleur. Les deux tests sont chronométrés; vous obtiendrez vos temps (en secondes) après avoir terminé les deux. Il est peu probable que vous terminiez le deuxième test en moins de temps que le premier.

Les lignes 5 et 6 définissent un tableau de chaînes, qui fait correspondre les noms des couleurs à leurs représentations numériques (par exemple, la couleur 1 est affectée au bleu).

Ensuite, les lignes 22 à 43 contiennent le code du premier test; notez les appels de sous-programmes, qui vérifient si vous avez entré la bonne couleur de mot.

Les lignes 122 à 142 contiennent le code du second test. Enfin, les lignes 275 et 280 affichent une approximation approximative du nombre de secondes que chaque test vous a pris pour terminer.

Le programme a besoin de plus d'options. Pour commencer, l'utilisateur doit être interrogé sur le nombre de mots que chaque test doit afficher (pour le moment, il est bloqué sur cinq mots). La saisie des couleurs est également fastidieuse, et fait donc perdre de précieuses secondes ; il doit certainement y avoir un meilleur moyen. Même l'affichage des mots eux-mêmes n'est pas idéal, ils sont trop petits.

4 'DÉFINIR LES COULEURS DANS UN TABLEAU (IGNORER LA COULEUR 3)
5 DIM C0L$(6) '
6 COL$(1)="BLEU":COL$(2)="VERT":COL$(6)="JAUNE"
7 COL$(4)="ROUGE":COL$(5)="VIOLET":COL$(3)="NOTHING"
10 KEY OFF:SCREEN 9:COLOR 15,0:CLS:COUNT1=0:COUNT2=0
12 RANDOMIZE TIMER
13 PRINT "LE TEST DE STROOP"
14 PRINT:PRINT "IL Y A DEUX TESTS QUE VOUS COMPLÉTEREZ LE PLUS RAPIDEMENT POSSIBLE."
15 PRINT "DANS LES DEUX TESTS, VOUS TAPEZ LA LETTRE DE LA *COULEUR* DU MOT"
16 PRINT "ET PAS LE MOT, Z=BLEU,X=VERT,C=ROUGE,V=VIOLET, B=JAUNES. LES CODES VONT"
17 PRINT "ÊTRE EN BAS DE L'ÉCRAN. Appuyez <ESPACE> POUR COMMENCER!"
18 IF INKEY$<>" " THEN 20
20 FOR LOOP=1 TO 5:CLS:COLOR 15:PRINT "TEST #1"
22 LOCATE 20,10:PRINT "Z=BLEU,X=VERT,C=ROUGE,V=VIOLET,B=JAUNE"
23 TEMPCOL=RWORD:RWORD=INT(1+6*RND(1)):IF RWORD=3 THEN 23
24 IF RWORD=TEMPCOL THEN 23
30 COLOR RWORD:LOCATE 10,35:PRINT COL$(RWORD): CONTINUE=0
31 I$=INKEY$
32 COUNT1=COUNT1+1
35 IF I$="Z" THEN GUESS=1:GOSUB 45
36 IF I$="X" THEN GUESS=2:GOSUB 45
37 IF I$="C" THEN GUESS=4:GOSUB 45
38 IF I$="V" THEN GUESS=5:GOSUB 45
39 IF I$="B" THEN GUESS=6:GOSUB 45
40 IF CONTINUE=1 THEN 42 ELSE 31
42 NEXT LOOP
43 GOTO 120 'LORSQUE LE TEST #1 EST EFFECTUÉ, VA A TEST #2
45 'SOUS-ROUTINE POUR LE TEST #1 POUR VOIR SI VOTRE CHOIX = LA COULEUR DU MOT
50 IF GUESS=RWORD THEN CONTINUE=1
60 RETURN
120 CLS:COLOR 15:PRINT:PRINT:PRINT:PRINT"Appuyez <ESPACE> Pour commencer le TEST #2"
121 IF INKEY$<>" " THEN 121
122 FOR LOOP=1 TO 5:CLS:COLOR 15:PRINT"TEST #2":LOCATE 20,10:PRINT "Z=BLEU,X=VERT,C=ROUGE,V=VIOLET,B=JAUNE"
123 RWORD=INT(1+6*RND(1)):IF RWORD=3 THEN 123
124 RCOLOR=INT(1+6*RND(1)):IF RCOLOR=3 THEN 124
125 IF RCOLOR=RWORD THEN 124
130 COLOR RCOLOR:LOCATE 10,35:PRINT COL$(RWORD):CONTINUE=0
131 I$=INKEY$
132 COUNT2=COUNT2+1
135 IF I$="Z" THEN GUESS=1:GOSUB 145
136 IF I$="X" THEN GUESS=2:GOSUB 145
137 IF I$="C" THEN GUESS=4:GOSUB 145
138 IF I$="V" THEN GUESS=5:GOSUB 145
139 IF I$="B" THEN GUESS=6:GOSUB 145
140 IF CONTINUE=1 THEN 142 ELSE 131
142 NEXT LOOP
143 GOTO 270 'LORSQUE LE TEST #2 EST EFFECTUÉ, AFFICHE LES RÉSULTATS
145 'SOUS-ROUTINE POUR LE TEST #2 POUR VOIR SI VOTRE CHOIX = COULEUR DU MOT
150 IF GUESS=RCOLOR THEN CONTINUE=1
160 RETURN
270 CLS:COLOR 15
275 PRINT "VOUS AVEZ PRIS ENVIRON ";COUNT1/80;"SECONDES POUR TERMINER LE TEST #1"
280 PRINT "VOUS AVEZ PRIS ENVIRON ";COUNT2/80;" SECONDES POUR TERMINER LE TEST #2"
295 PRINT:PRINT "APPUYER <SPACE> ESSAYER À NOUVEAU,"
296 PRINT "OR <ESCAPE> POUR QUITTER..."
300 Q$=INKEY$
310 IF Q$=" " THEN 10
320 IF Q$=CHR$(27) THEN CLS:END
330 GOTO 300