Allons au Point

GW-BASIC  (PC-BASIC)

Initiation au langage Basic

L'une des fonctionnalités les plus intéressantes de GW-BASIC est sa capacité à afficher des graphiques précis, variés et faciles à utiliser appelés "graphiques haute résolution".

À quel point ces graphiques sont-ils faciles à utiliser ?

Eh bien, commençons par l'élément graphique le plus basique (jeu de mots) - un point et construisons à partir de là.

GW-BASIC simplifie l'affichage d'un point sur l'écran.

Tapez le programme suivant et voyez :

10 SCREEN 9
20 CLS
30 PSET (10,20),7
40 GOTO 40

Exécutez maintenant le programme. L'écran devrait être noir, et si vous regardez attentivement, vous pouvez voir un petit point blanc dans le coin supérieur gauche. Ce point a été mis là par le PSET (sélection d'un point dans la ligne 30).

PSET affiche un point à un endroit spécifié sur l'écran lors de l'utilisation du mode graphique.

Syntaxe:

PSET(x,y)[,couleur]

Commentaires:

(x,y) représente les coordonnées du point.

couleur est la couleur du point.

Les coordonnées peuvent être données sous forme absolue ou relative.

La forme absolue (x absolu, y absolu) est plus courante et se réfère directement à un point sans tenir compte du dernier point référencé.

Par exemple:

(10,10)

Forme relative

STEP (x décalage, y décalage) est un point relatif au point le plus récent référencé.

Par exemple:

STEP(10,10)

Les valeurs de coordonnées peuvent être au-delà du bord de l'écran. Cependant, les valeurs en dehors de la plage d'entiers (-32768 à 32767) provoquent une erreur "Overflow".

(0,0) est toujours le coin supérieur gauche et (639,349) est le coin inférieur droit pour SCREEN 9.

Voir les instructions SCREEN, COLOR, PALETTE pour plus d'informations.

Même si vous ne pouvez pas le voir, l'ordinateur a divisé votre écran en une grille de près de 223 011 points - 639 en largeur et 349 en bas - afin que vous puissiez placer un point précisément là où vous le souhaitez.

Regardez à nouveau la ligne 30 et voyez comment PSET spécifie la position du point (10 à gauche et 20 en bas):

30 PSET (10,20),7

Voici la déclaration que vous utiliseriez pour définir un point rouge au centre de l'écran :

PSET (319,174),4

Ajoutez maintenant une ligne de programme qui définit un point rouge dans le coin inférieur droit (639 au-dessus et 349 en bas).

Est-ce la ligne que vous avez utilisée ?

PSET (639,349),4

Si oui, félicitations !

Vous avez fait valoir votre point de vue. Exécutez votre programme et vous verrez.

Ce qui suit trace une ligne diagonale de (0,0) à (100,100) dans SCREEN 1 (320 × 200 pixels).

10 CLS
20 SCREEN 1
30 FOR I=0 TO 100
40 PSET (I,I)
50 NEXT
60 LOCATE 14,1

Le programme ci-dessous trace une ligne diagonale de (0,0) à (100,100) dans SCREEN 1,2,7,8,9

10 SCREEN 1
20 LOCATE 1,5:PRINT "SCREEN 1, 320 × 200 pixels, 40 caractères"
30 GOSUB 1000
40 SCREEN 2
50 LOCATE 1,5:PRINT "SCREEN 2, 640 × 200 pixels 80 caractères"
60 GOSUB 1000
70 SCREEN 7
80 LOCATE 1,5:PRINT "SCREEN 7, 320 × 200 pixels, 40 caractères"
90 GOSUB 1000
100 SCREEN 8
110 LOCATE 1,5:PRINT "SCREEN 8, 640 × 200 pixels, 80 caractères"
120 GOSUB 1000
130 SCREEN 9
140 LOCATE 1,5:PRINT "SCREEN 9, 640 × 350 pixels, 80 caractères"
150 GOSUB 1000
160 LOCATE 14,1
170 SCREEN 0
180 END
1000 FOR I=0 TO 100
1010 PSET (I,I)
1020 NEXT
1030 LOCATE 14,1:PRINT"Appuyez sur une touche pour continuer"
1040 A$=INKEY$:IF A$="" THEN 1040
1050 RETURN

Mais qu'en est-il de la couleur ?

À présent, vous avez probablement compris que vous pouvez changer les couleurs en remplaçant c par un nombre différent dans la plage de 0 à 15.

Voici la liste des 16 principales couleurs

0 Noir
1 Bleu
2 Vert
3 Cyan
4 Rouge
5 Magenta
6 Marron
7 Blanc
8 Gris
9 Bleu clair
10 Vert clair
11 Cyan clair
12 Rouge clair
13 Magenta clair
14 Jaune
15 Blanc haute intensité

Pour SCREEN 9, il y a 64 couleurs ....

Maintenant, vous le voyez ... maintenant, vous ne le voyez pas

Des suppositions comment désactiver un point?

Voici un indice : c'est facile et c'est lié à la couleur.

Vous voyez, vous n'éteignez pas vraiment le point, vous changez simplement sa couleur pour qu'il se fonde dans l'arrière-plan.

Vous faites cela avec une nouvelle déclaration :

PRESET (réinitialisation du point). PRESET "sait" que vous voulez utiliser la couleur d'arrière-plan, vous n'avez donc pas besoin de donner la couleur.

PRESET (h,v) réinitialise un point sur l'écran graphique actuel

Programme faites-le vous même

Apprenez à connaître les positions des points sur votre écran de télévision en utilisant une feuille de travail de l'écran graphique (Papier millimétrique).

Sélectionnez plusieurs points sur la feuille de travail, identifiez-les en fonction de leurs coordonnées (X,Y) et affichez-les à l'écran à l'aide du programme que nous avons utilisé pour vous aider à démarrer.

Ne modifiez aucune ligne de programme sauf celles qui contiennent P5ET(h,v),c.

10 SCREEN 9
20 CLS
30 PSET (10,20),7
40 GOTO 40

Programme faites-le vous même

Rappelez-vous la fonction RND (aléatoire) ?

Sinon, révisez-la, voir Jeux de chances; puis écrivez un court programme qui remplit l'écran avec des points et des couleurs aléatoires.

5 SCREEN 1 '320 × 200 pixels
10 RANDOMIZE TIMER
20 CLS
30 X = INT(320*RND(1)+1)
40 Y = INT(200*RND(1)+1)
50 C = INT(15*RND(1)+1)
60 PSET(X,Y),C
70 GOTO 30

Le dernier Point

Avant de terminer cette section, nous voulons faire une dernière remarque. Vous pouvez utiliser POINT pour savoir de quelle couleur est n'importe quel point à l'écran.

POINT(x,y)

5 SCREEN 7 '320 × 200 pixels
10 RANDOMIZE TIMER
20 CLS
30 X = INT(320*RND(1)+1)
40 Y = INT(200*RND(1)+1)
50 C = INT(15*RND(1)+1)
60 PSET(X,Y),C
70 IF POINT (X,Y)=12 THEN GOTO 90
80 GOTO 30
90 PRINT "La couleur du point "X Y" est Rouge clair"