Regarder l'horloge

Vous êtes maintenant prêt à montrer à votre ordinateur comment lire l'heure.

Taper:

10 FOR Z= 1 TO 460*2
20 NEXT Z
30 PRINT " JE COMPTE JUSQU'A 920"

Exécutez le programme. Soyez patient et attendez quelques secondes. Deux secondes, pour être précis. Il faut deux secondes à votre ordinateur pour compter jusqu'à 920.

Les lignes 10 et 20 définissent une pause de la minuterie dans votre programme. En faisant compter jusqu'à 920 à l'ordinateur, vous maintenez l'ordinateur occupé pendant deux secondes.

Comme vous pouvez le constater, il s'agit d'un travail préparatoire pour un chronomètre.

Effacez le programme et tapez :

10 PRINT "COMBIEN DE SECONDES?"
20 INPUT S
30 FOR Z = 1 TO 460*S
40 NEXT Z
50 PRINT S " SECONDES SONT PASSÉES ! ! !"

Exécutez le. Saisissez le nombre de secondes que vous souhaitez chronométrer sur votre chronomètre.

PROGRAMME faites le vous même 1

Cela aiderait si le chronomètre pouvait sonner une sorte d'alarme. Ajoutez des lignes à la fin du programme pour lui donner une alarme.

Voici le programme que nous avons écrit :

10 PRINT "COMBIEN DE SECONDES?"
20 INPUT S
30 FOR Z = 1 TO 460*S
40 NEXT Z
50 PRINT S " SECONDES SONT PASSÉES ! ! !"
60 FOR T = 120 TO 180
70 SOUND T,1
80 NEXT T
90 FOR T = 150 TO 140 STEP -1
100 SOUND T,1
110 NEXT T
120 GOTO 50

Remarquez la ligne GOTO à la fin du programme. Le message continue de s'afficher et l'alarme continue de sonner jusqu'à ce que vous appuyiez sur BREAK ou CTRL+C.

Compter dans le temps

Avant d'en faire plus avec l'horloge, demandez à l'ordinateur de compter dans le temps. Ce concept vous deviendra précieux sous peu. (mon précieux comme dirait Gollum ...)

Tapez ce nouveau programme :

10 FOR X = 1 TO 3
20 PRINT "X = " X
30 FOR Y = 1 TO 2
40 PRINT, "Y=" Y
50 NEXT Y
60 NEXT X

Remarquer la virgule à la ligne 40. Essayez sans la virgule. La virgule fait afficher "Y= " Y sur la colonne suivante.

Appelez cela un compte dans un compte ou une boucle dans une boucle----ce que vous préférez.

Les programmeurs appellent cela une "boucle imbriquée". Voici ce que fait le programme :

I. Il compte X de 1 à 3. A chaque fois il compte X :
    A. Il affiche la valeur de X
    B. Il compte Y de 1 à 2. A chaque fois il compte Y :
            1. Il affiche la valeur de Y

Chaque fois que vous mettez une boucle à l'intérieur d'une autre boucle, vous devez fermer la boucle intérieure avant de fermer la boucle extérieure :

Correct                                Incorrect

Faire une horloge

Avec ces outils, vous pouvez faire faire beaucoup plus à l'ordinateur.

Tapez ceci :

10 FOR S = 0 TO 59
20 PRINT S
30 SOUND 150,2
40 FOR T = 1 TO 390
50 NEXT T
60 NEXT S
70 PRINT"1 MINUTE EST PASSE"

Exécutez le programme. C'est ce que ça fait:

I. Il compte les secondes de 0 à 59. A chaque fois il compte une seconde :
    A. Il affiche la second.
    B. Il émet une tonalité.
    C. Il s'arrête assez longtemps pour qu'une seconde passe.
II. Lorsqu'il a fini de compter toutes les secondes de 0 à 59, il affiche un message indiquant qu'une minute s'est écoulée.

Il existe un moyen d'améliorer l'apparence de ce programme. Ajoutez cette ligne pour effacer l'écran :

15 CLS

Exécutez maintenant le programme. Cette fois, l'ordinateur passe par ces étapes :

I. Il compte les secondes de 0 à 59 (lignes 10 et 60). Chaque lime compte une seconde :
    A. Il efface l'écran (ligne 15).
    B. II affiche la seconde (ligne 20).
    C. Il émet une tonalité (ligne 30).
    D. Il fait une pause suffisamment longue pour qu'une seconde passe (lignes 40 et 50).
II. Lorsqu'il a fini de compter toutes les secondes de 0 à 59, il affiche un message indiquant qu'une minute s'est écoulée (ligne 70).

En utilisant cela comme base, il est facile de crée une horloge à part entière :

10 FOR H = 0 TO 23
20 FOR M = 0 TO 59
30 FOR S = 0 TO 59
40 CLS
50 PRINT H": "M": "S
60 SOUND 150,2
70 FOR T = 1 TO 375
80 NEXT T
90 NEXT S
100 NEXT M
110 NEXT H

Voici un aperçu de ce que fait l'ordinateur dans ce programme :

I. Il compte les heures de 0 10 23 (ligne 10). A chaque fois il compte une nouvelle heure :
    A. Il compte les minutes de 0 à 59 (ligne 20). A chaque fois cela compte une nouvelle minute :
    1. Il compte les secondes de 0 à 59 (lignes 30 et 90). A chaque fois il compte une nouvelle seconde : :
        a. II efface l'écran (ligne 40).
        b. Il affiche l'heure, la minute et la seconde (ligne 50).
        c. Ca sonne un seul (ligne 60).
        d. Il s'arrête assez longtemps pour qu'une seconde passe (Unes 70 et 80).
    2. Lorsqu'il a fini de compter les 59 secondes, il revient à la ligne 20 pour la minute suivante (ligne 100).
    B. Quand il a fini de compter toutes les 59 minutes, il recule de 10 lignes pour la prochaine heure (ligne 110).
II. Lorsqu'il a fini de compter toutes les heures (0-23), le programme se termine.

En ajoutant cette ligne, 120 GOTO 10, l'horloge fonctionnera perpétuellement.

Vous avez du mal avec ce programme ? Ignorez-le pour l'instant.

Cela vous semblera facile plus tard.

PROGRAMME faites le vous même 2

Entre les lignes 90 et 100, vous pouvez ajouter des tonalités qui retentiront à chaque minute. Écrivez un programme qui fait cela.

PROGRAMME faites le vous même 3

Écrivez un programme qui fait que votre ordinateur affiche chacune de ses différentes couleurs pendant 1 seconde chacune.

PROGRAMME 2

Lignes ajoutées au programme de l'horloge :

92 FOR T=200 TO 210 STEP 5
94 SOUND T, 1
95 NEXT T
97 FOR T=210 TO 200 STEP -5
98 SOUND T, 1
99 NEXT T

PROGRAMME 3

10 SCREEN 9
20 COLOR 7,0
30 CLS
40 FOR C = 0 TO 14
50 COLOR 1,C
30 FOR X = 1 TO 460
60 NEXT X
70 NEXT C
80 COLOR 7,0